// copyright (c) 1997-2018 Martin Wynne.   All rights reserved.

function aq25offset(xs:extended; var k:extended):extended;   // return offset at xs on turnout road centre-line.
                                                             // also return the angle in k.
var
  temp:extended;
  x,xlim,rto:extended;

  curve_endx:extended;

                    ////////////////////////////////////////////////////////////

                    procedure do_gaunt;

                    begin
                      RESULT:=g/2+h;
                      k:=0;
                    end;
                    ////////////////////////////////////////////////////////////

                    procedure do_parallel_xing;

                    begin
                      if xs<retx
                         then begin
                                RESULT:=g/2+(xs-dpx)/k3n;   // straight section beyond crossing point.
                                k:=k3;
                                EXIT;
                              end;

                      if xs>retrorgx
                         then begin
                                RESULT:=trtscent+g/2;       // parallel section beyond return curve.
                                k:=0;
                                EXIT;
                              end;

                      if retr<minfp then retr:=minfp;
                      temp:=(retrorgx-xs)/retr;
                      if ABS(temp)<1.0 then k:=ARCSIN(temp)
                                       else k:=Pi/2;

                      RESULT:=retrorgy+retr*COS(k);         // return curve section.
                    end;
                    ////////////////////////////////////////////////////////////

                    procedure do_turnout_curve;

                    begin
                      rto:=tradius-g/2;

                      if ABS(rto)<minfp      // abandon ship ???
                         then begin
                                abandon_calcs:=True;
                                RESULT:=0;
                                k:=0;
                                EXIT;
                              end;

                      xlim:=ABS(rto)*0.98;   // 0.98*radius, arbitrary x limits to turnout curve.  0.79.a

                      repeat
                        if xs>(torgx+xlim)
                           then begin
                                  x:=xlim;   // forward limit x from rad centre.
                                  BREAK;
                                end;

                        if xs<(torgx-xlim)
                           then begin
                                  x:=0-xlim; // backward limit x from rad centre.
                                  BREAK;
                                end;

                        x:=xs-torgx;         // ok, x from rad centre.
                        BREAK;
                      until 0<>0;

                      try
                        temp:=SQR(rto)-SQR(x);
                        RESULT:=torgy-SQRT(temp)*SGZ(rto);   // calc turnout curve.
                        k:=ARCSIN(x/rto);                    // and gradient angle.
                      except
                        abandon_calcs:=True;       // abandon ship. Cannot be if x is under 90 degrees ?
                        RESULT:=0;
                        k:=0;
                      end;//try
                    end;
                    ////////////////////////////////////////////////////////////

                    procedure do_regular_beyond_curve_end;

                    begin

                      if xs<tcpx        // in front of crossing, for regular, parallel
                         then begin
                                RESULT:=g/2+(xs-dpx)/k3n;       // straight centre-line from CESP to crossing
                                k:=k3;
                                EXIT;
                              end;

                      if (xing_calc_i=0) and (retpar_i=1)       // parallel crossing...
                         then begin
                                do_parallel_xing;
                                EXIT;
                              end;

                        // regular or generic crossing beyond TCP...

                      RESULT:=g/2+(xs-dpx)/k3n;   // straight section beyond crossing
                      k:=k3;
                    end;
                    ////////////////////////////////////////////////////////////

begin
  RESULT:=g/2;    // init defaults
  k:=0;

  if (gaunt=True) and (xs<torgx)
     then begin
            do_gaunt;
            EXIT;
          end;

  if xing_calc_i=1     // curviform crossing, all templates
     then begin
            do_turnout_curve;  // turnout curve runs through
            EXIT;
          end;

  if tradius_is_straight=True  // regular diamond, straight line from DP to TCP ...
     then begin
            do_regular_beyond_curve_end;
            EXIT;
          end;

  curve_endx:=torgx+(tradius-g/2)*SIN(k3);  // turnout curve end CESP or TCP

  if xs<curve_endx
     then begin
            do_turnout_curve;
            EXIT;
          end;

  do_regular_beyond_curve_end;

end;
//______________________________________________________________________________

procedure turnroad_cl;       // generate turnout road track centre-line

var
  xs,ys,xe:extended;
  dummy:extended;
  curve_startx:extended;  // 213a

begin
  if plain_track=True then EXIT;

  if (half_diamond=True) or (gaunt=True)            // mods 213a
     then xs:=blank_start(0)                        // start at origin
     else begin
            curve_startx:=torgx+(tradius-g/2)*SIN(k2);  // switch curve end / turnout curve start
            xs:=blank_start(curve_startx);              // turnout start
          end;

  case turnout_road_i of  // 209a

        -1: xe:=txpx;     // stop at crossover mid-point

       0,1: begin
              if retpar_i=1 then begin                                     // parallel crossing...
                                   if turnout_road_i=1 then xe:=turnoutx   // long turnout road - stop at end of turnout
                                                       else xe:=trpx;
                                 end
                            else xe:=vendx;     // stop at end of vee rail
            end;

       2,3: if turnoutx>(xorg+min_turnout_road_endx) then xe:=xorg+turnout_road_endx      // 2=adjustable turnout road      3 added  217a
                                                     else xe:=turnoutx;

       else xe:=turnoutx;  // ???

  end;//case

  if (turnout_road_i<2) and (xe>turnoutx) then xe:=turnoutx;   // 209a           was <>2 217a

  if xs>(xe-minfp) then EXIT;  // !!! 0.76.a  18-1-2002

  repeat
    if xs>xe then xs:=xe;        // ensure we hit the end

    ys:=aq25offset(xs,dummy);    // get offset to centre-line (angle not used)

    if (f28000(25,xs,ys)=1) or (xs>=xe) then BREAK;  // do curving on xs,ys and put in array (aq=25)
    xs:=xs+incx;                                     // increment xs.
  until 0<>0;
end;
//______________________________________________________________________________